LKML Archive on lore.kernel.org
help / color / mirror / Atom feed
From: Julia Lawall <Julia.Lawall@lip6.fr>
To: Benjamin Herrenschmidt <benh@kernel.crashing.org>
Cc: kernel-janitors@vger.kernel.org,
	Paul Mackerras <paulus@samba.org>,
	Michael Ellerman <mpe@ellerman.id.au>,
	linuxppc-dev@lists.ozlabs.org, linux-kernel@vger.kernel.org
Subject: [PATCH 0/6] add missing of_node_put
Date: Fri, 20 Nov 2015 21:33:18 +0100	[thread overview]
Message-ID: <1448051604-25256-1-git-send-email-Julia.Lawall@lip6.fr> (raw)

The various for_each device_node iterators performs an of_node_get on each
iteration, so a break out of the loop requires an of_node_put.

The complete semantic patch that fixes this problem is
(http://coccinelle.lip6.fr):

// <smpl>
@r@
local idexpression n;
expression e1,e2;
iterator name for_each_node_by_name, for_each_node_by_type,
for_each_compatible_node, for_each_matching_node,
for_each_matching_node_and_match, for_each_child_of_node,
for_each_available_child_of_node, for_each_node_with_property;
iterator i;
statement S;
expression list [n1] es;
@@

(
(
for_each_node_by_name(n,e1) S
|
for_each_node_by_type(n,e1) S
|
for_each_compatible_node(n,e1,e2) S
|
for_each_matching_node(n,e1) S
|
for_each_matching_node_and_match(n,e1,e2) S
|
for_each_child_of_node(e1,n) S
|
for_each_available_child_of_node(e1,n) S
|
for_each_node_with_property(n,e1) S
)
&
i(es,n,...) S
)

@@
local idexpression r.n;
iterator r.i;
expression e;
expression list [r.n1] es;
@@

 i(es,n,...) {
   ...
(
   of_node_put(n);
|
   e = n
|
   return n;
|
+  of_node_put(n);
?  return ...;
)
   ...
 }

@@
local idexpression r.n;
iterator r.i;
expression e;
expression list [r.n1] es;
@@

 i(es,n,...) {
   ...
(
   of_node_put(n);
|
   e = n
|
+  of_node_put(n);
?  break;
)
   ...
 }
... when != n

@@
local idexpression r.n;
iterator r.i;
expression e;
identifier l;
expression list [r.n1] es;
@@

 i(es,n,...) {
   ...
(
   of_node_put(n);
|
   e = n
|
+  of_node_put(n);
?  goto l;
)
   ...
 }
...
l: ... when != n// </smpl>

---

 arch/powerpc/kernel/btext.c                   |    4 +++-
 arch/powerpc/kernel/machine_kexec_64.c        |    4 +++-
 arch/powerpc/platforms/cell/iommu.c           |    1 +
 arch/powerpc/platforms/embedded6xx/hlwd-pic.c |    1 +
 arch/powerpc/platforms/powernv/opal-lpc.c     |    1 +
 arch/powerpc/platforms/pseries/setup.c        |    3 ++-
 6 files changed, 11 insertions(+), 3 deletions(-)

             reply	other threads:[~2015-11-20 20:45 UTC|newest]

Thread overview: 8+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2015-11-20 20:33 Julia Lawall [this message]
2015-11-20 20:33 ` [PATCH 1/6] powerpc/6xx: " Julia Lawall
2015-11-20 20:33 ` [PATCH 2/6] powerpc/pseries: " Julia Lawall
2015-11-20 20:33 ` [PATCH 3/6] powerpc/powernv: " Julia Lawall
2015-11-20 20:33 ` [PATCH 4/6] powerpc/kexec: " Julia Lawall
2015-11-20 20:33 ` [PATCH 5/6] powerpc/btext: " Julia Lawall
2015-11-20 20:33 ` [PATCH 6/6] powerpc/cell: " Julia Lawall
2021-11-25  9:35 ` (subset) [PATCH 0/6] " Michael Ellerman

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=1448051604-25256-1-git-send-email-Julia.Lawall@lip6.fr \
    --to=julia.lawall@lip6.fr \
    --cc=benh@kernel.crashing.org \
    --cc=kernel-janitors@vger.kernel.org \
    --cc=linux-kernel@vger.kernel.org \
    --cc=linuxppc-dev@lists.ozlabs.org \
    --cc=mpe@ellerman.id.au \
    --cc=paulus@samba.org \
    --subject='Re: [PATCH 0/6] add missing of_node_put' \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).